Skriptgerüst für VBScript

Aller Anfang ist schwer. Dies ist ein Beispielgerüst für ein einfaches ActiveScript für FixFoto® mit Versions- und Ausführungskontrolle, dass mit markierten Bildern arbeitet.

Anmerkung: Mit ** markierte Einträge sollten mit eigenen Werten ersetzt werden
'* **ScriptDateiname**
'* **(C)Copyrightangabe**
'* Stand: **23.01.2011**

'* FFSubmenu=**Meine Skripte**
'* FFName=**Mein erstes Skript**
'* FFMinVer=**2.78**

Option Explicit
 
''' Globale Variablen '''
'Standardobjekt, dass meist gebraucht wird.
Dim fso
 
'Prüfen, ob Umgebung und Version passen
If CheckForRun() = True Then Main
 
'Aufräumen!
Set fso = Nothing
 
 
 
 
 
Sub Main
    ''' Lokale Variablen '''
    Dim i
    Dim aFiles
 
    ''' Zuweisung globaler Variablen '''
    Set fso = CreateObject("Scripting.FileSystemObject")
 
    'Markierte Bilder einlesen
    If FF_GetImageCount > 0 Then
        ReDim aFiles(FF_GetImageCount() - 1)
        For i = 0 To FF_GetImageCount() - 1
            aFiles(i) = FF_GetImageName(i)
        Next
    Else
        MsgBox "Keine Bilder geladen!", vbInformation
        'Programm sauber abbrechen durch Verlassen der Methode
        Exit Sub
    End If
 
    ''' Hier kommen die Anweisungen oder die Verzweigung in ein Unterprogramm
    ''' ...
    ''' ...
End Sub
 
'Überprüft, ob Script ausgeführt werden darf
Function CheckForRun()
    Dim sVersion
    Dim Tmp
 
    CheckForRun = False
 
    'Hier wird die minimale Version definiert
    sVersion = "2.79.1"
 
    On Error Resume Next
 
    Tmp = FF_GetImageCount()
 
    If Err.Number = 500 Then
        MsgBox "Laufzeitumgebung ist nicht FixFoto" & vbCRLF & "Diese Laufzeitumgebung wird nicht unterstützt!", vbCritical, "Laufzeitumgebung"
        Err.Clear
        On Error Goto 0
        Exit Function
    End If
 
    Tmp = FF_GetMajor()
 
    If Err.Number = 500 Then
        MsgBox "FixFoto Version vor 2.71.18" & vbCRLF & "Diese Version wird nicht unterstützt!", vbCritical, "Laufzeitumgebung"
        Err.Clear
        On Error Goto 0
        Exit Function
    End If
 
    On Error Goto 0
 
    If Not CheckForFunction(sVersion) Then
        MsgBox "FixFoto Version vor " & sVersion & vbCRLF & "Diese Version wird nicht unterstützt!", vbCritical, "Laufzeitumgebung"
        Exit Function
    End If
 
    CheckForRun = True
End Function
 
'Überprüft, ob FF-Version für eine Funktion hoch genug ist
Function CheckForFunction(ByVal sVersion)
    Dim aVersion
    Dim dVersion
    Dim dFF
 
    aVersion = Split(sVersion, ".")
    dVersion = CDbl(aVersion(0)) + CDbl(aVersion(1)) / 1000 + CDbl(aVersion(2)) / 1000000
    dFF = CDbl(FF_GetMajor) + CDbl(FF_GetMinor) / 1000 + CDbl(FF_GetBuild) / 1000000
    If dVersion <= dFF Then CheckForFunction = True Else CheckForFunction = False
End Function